易语言“循环体”（变量/计次/判断/循环）初步理解和运用

引续

因为变量/计次/判断/循环等循环体而经常蒙了，不知其有何用处，具体用法又是什么？

我们先来看看易语言知识库给与的解释

1. 变量循环：执行本命令将利用变量对循环体内的命令进行循环执行。
2. 计次循环：执行本命令将把循环体内的命令重复执行指定的次数。
3. 判断循环：本命令根据提供的逻辑参数的值，来决定是否进入循环。
4. 循环判断：执行本命令后将顺序执行下一条命令进入程序循环。

代码解释

变量循环语法：变量循环首 (起始值,目标值 , 递增值, 循环变量)

1. 起始值：顾名思义也就是开始的值
2. 目标值：需要循环多少次
3. 递增值：每次循环需要递增多少
4. 循环变量：用来记录已经循环的次数

定义：当我们将目标值定义为9，初始值定义为1，递增值定义为1的时候。他将输出1到9的数字，也就是说他是根据程序员定义的初始值来进行循环第一次循环的，继续按照程序员定义的递增值进行增加。当循环次数等于目标值就会结束循环。

文章源自楠竹林-https://www.nanzl.com/archives/831

.变量循环首 (1, 9, 1, 循环变量)

    调试输出 (循环变量)

.变量循环尾 ()

计次循环语法：计次循环首 (循环次数, 记录变量 )

1. 循环次数：需要进行循环的次数
2. 记录变量：用于记录已经循环的次数

定义：他的初始值默认为1，也就是它会从1开始计数，当数值等于程序员定义的循环次数就会结束循环。当我们把循环次数定义为9，也会输出1到9的数字。

 文章源自楠竹林-https://www.nanzl.com/archives/831

.计次循环首 (9, 循环变量)
    调试输出 (循环变量)
.计次循环尾 ()

判断循环语法：判断循环首 (循环条件)

1. 循环条件：进入循环的条件

定义：代码执行到这里，达到循环条件，就会进入循环。循环条件等于程序员定义的循环条件就会跳出循环。例如我们定义循环条件为小于9，那么他会输出0到8的数字。但是如果我们加上一个小于等于9，那么他会输出0到9的数字。因为他的初始值为0，也就是从0开始执行循环。

.判断循环首 (循环变量 ≤ 9)
    调试输出 (循环变量)
    循环变量 ＝ 循环变量 ＋ 1

.判断循环尾 ()

循环判断语法：循环判断尾（循环条件）

1. 循环条件：进入循环的条件

定义：循环判断的定义实际上和判断循环一致，唯一的区别在于判断循环是需要达到循环条件才能进入循环，而循环判断是先进入循环再判断循环条件。如果循环条件未达到即跳出循环。文章源自楠竹林-https://www.nanzl.com/archives/831

它们有什么共同性，区别又是什么

1. 计次循环/变量循环：默认初始值为1 ，变量循环可以定义初始值。它们都是按照计数进行循环。
2. 判断循环/循环判断：都是条件循环。唯一的区别判断循环是先判断再循环，循环判断是先循环再判断。

进一步利用他们做一个99乘法表

.版本 2

.子程序 _按钮1_被单击
.局部变量 第一次循环, 整数型
.局部变量 第二次循环, 整数型


' 计次循环实现99乘法表
编辑框_显示.加入文本 (“计次循环实现99乘法表”)
.计次循环首 (9, 第一次循环)
    .计次循环首 (第一次循环, 第二次循环)
        编辑框_显示.加入文本 (到文本 (第一次循环) ＋ “X” ＋ 到文本 (第二次循环) ＋ “=” ＋ 到文本 (第一次循环 × 第二次循环) ＋ “  ”)
    .计次循环尾 ()
    编辑框_显示.加入文本 (#换行符)
.计次循环尾 ()
第一次循环 ＝ 0  ' 为了防止计次叠加
第二次循环 ＝ 0
' 变量循环实现99乘法表
编辑框_显示.加入文本 (#换行符)
编辑框_显示.加入文本 (“变量循环实现99乘法表”)
编辑框_显示.加入文本 (#换行符)
.变量循环首 (1, 9, 1, 第一次循环)
    .变量循环首 (1, 第一次循环, 1, 第二次循环)
        编辑框_显示.加入文本 (到文本 (第一次循环) ＋ “X” ＋ 到文本 (第二次循环) ＋ “=” ＋ 到文本 (第一次循环 × 第二次循环) ＋ “  ”)
    .变量循环尾 ()
    编辑框_显示.加入文本 (#换行符)
.变量循环尾 ()
第一次循环 ＝ 0  ' 为了防止计次叠加
第二次循环 ＝ 0
' 判断循环实现99乘法表
编辑框_显示.加入文本 (#换行符)
编辑框_显示.加入文本 (“判断循环实现99乘法表”)
编辑框_显示.加入文本 (#换行符)
.判断循环首 (第一次循环 ＜ 9)
    第一次循环 ＝ 第一次循环 ＋ 1
    第二次循环 ＝ 0
    .判断循环首 (第二次循环 ＜ 第一次循环)
        第二次循环 ＝ 第二次循环 ＋ 1
        编辑框_显示.加入文本 (到文本 (第一次循环) ＋ “X” ＋ 到文本 (第二次循环) ＋ “=” ＋ 到文本 (第一次循环 ＋ 第二次循环) ＋ “  ”)
    .判断循环尾 ()
    编辑框_显示.加入文本 (#换行符)
.判断循环尾 ()